indesign-script - Bilder100ProzentCS2.scpt

Das folgende AppleScript geht durch alle in einem InDesign-CS2-Dokument
importierten Bilder. Wenn die Bildgrösse nicht 100% ist, wird das Bild
in Photoshop CS2 geöffnet, skaliert, geschärft und gesichert. Zuletzt
in InDesign CS2 aktualisiert und die Bildgrösse auf 100% gesetzt.

*****
Disclaimer:
Nur auf eigene Gefahr verwenden. Von allen InDesign-Dokumenten und
den Bilddateien zuerst Backups erstellen, bevor das Script ausgeführt wird.
Die importierten Originaldateien der Bilder werden überschrieben.
Die Namen der Dateien werden unverändert übernommen.
*****

Den Code als normales AppleScript (nicht als Programm) sichern und die
Datei im Ordner "Scripts" (im Ordner "Presets" des Programm-Ordners von
InDesign-CS) unterbringen. Dann kann das Script bequem mit Doppelklick
ab Scriptpalette gestartet werden.

Mit dieser Version 05 werden eventuelle Spiegelungen vorübergehend aufgehoben und dann wieder zugewiesen.

Und zum Ausschliessen von Vektor- und Textdateien wird nicht mehr der File Type getestet, sondern die Information der effektiven ppi-Werte.

(*Bilder100ProzentCS2_05d  
(basierend auf "ResampleImages24.as", einem Script für CS2 von Jeff Lambert)   
Dieses AppleScript geht durch alle in einem InDesign-CS2-Dokument importierten Bilder.  
Wenn die Bildgrösse nicht 100% ist, wird das Bild in Photoshop CS2 geöffnet, skaliert, geschärft und gesichert.  
Zuletzt in InDesign CS2 aktualisiert und die Bildgrösse auf 100% gesetzt.  
© 30.05.08  /  Hans Häsler, Châtelard 52, CH-1018 Lausanne  /  E-mail: hsa@ringier.ch   
*) 
tell application "Adobe InDesign CS2" 
 activate 
 set processedLinks to {} 
 -- wenn die Transformations-Vorgaben nicht als 'transformations are totals' definiert sind,  
 -- müssen sie angepasst werden, damit das Script richtig funktionieren kann  
 if transformations are totals of transform preferences is false then 
  set oldTransPrefs to properties of transform preferences 
  set transformations are totals of transform preferences to true 
  set show content offset of transform preferences to true 
  set dimensions include stroke weight of transform preferences to true 
  set transform content of transform preferences to true 
  set resetTrans to true 
 else 
  set resetTrans to false 
 end if 
 tell layout window 1 
  set oldAnchor to transform reference point 
  set transform reference point to center anchor 
 end tell 
 tell document 1 
  -- falls die Masseinheiten nicht Punkte sind, müssen sie vorübergehend geändert werden   
  -- damit das Script korrekt ausgeführt werden kann  
  if horizontal measurement units of view preferences is not points or ¬ 
   vertical measurement units of view preferences is not points then 
   set oldViewPrefs to properties of view preferences 
   set horizontal measurement units of view preferences to points 
   set vertical measurement units of view preferences to points 
   set resetUnits to true 
  else 
   set resetUnits to false 
  end if 
  -- die Liste der Links aufstellen  
  set linksList to every link 
  -- Rückwärts-Schleife durch die Elemente der Liste  
  repeat with i from (count linksList) to 1 by -1 
   set curLink to item i of linksList 
   set curImage to parent of curLink 
   -- mögliche Vektor- oder Text-Dateien ausschliessen  
   set okay to false 
   try 
    effective ppi of curImage 
    set okay to true 
   end try 
   if okay then 
    set imgName to name of curLink 
    set curFrame to parent of curImage 
    -- die Skalierungsprozente des Rahmens auf 100% zurücksetzen   
    reset scaling of curFrame 
    -- den Bildpfad feststellen  
    set imgPath to file path of item i of linksList as Unicode text 
    -- die Position des Bildes feststellen  
    set imgPos to geometric bounds of curImage 
    -- die Bildgrössen speichern  
    tell curImage 
     set {horVal, verVal} to {absolute horizontal scale, absolute vertical scale} 
    end tell 
    -- wenn eine Spiegelung vorhanden ist, diese vorübergehend aufheben  
    tell curImage 
     set {x, y} to {horizontal scale, vertical scale} 
     set rotAng to rotation angle 
     if y is less than 0 then 
      set {horizontal scale, vertical scale} to {x, y + (0 - (y * 2))} 
     end if 
     if rotAng is 180 then 
      set rotation angle to 0 
     end if 
    end tell 
    -- wenn die Bildgrösse anders als 100% ist und die Datei noch nicht in Photoshop skaliert worden ist, dann ...  
    if imgPath is not in processedLinks and horVal is not 100 then 
     if verVal is less than 0 then 
      set verVal to verVal + (0 - (verVal * 2)) 
     end if 
     set filePath to my resizeImage(imgPath, horVal, verVal) 
     if filePath is not "" then 
      relink curLink to filePath 
      -- beim Updaten des Links wird das alte Link entfernt und InDesign gibt das neue zurück  
      set curLink to update curLink 
      set curImage to parent of curLink 
      set curFrame to parent of curImage 
      -- die Bildgrössen auf 100 setzen  
      set properties of curImage to {geometric bounds:imgPos} 
      resize curImage horizontal scale 100 vertical scale 100 around center anchor ¬ 
       without considering current scale and considering parents scale 
      -- an die Liste den Pfad des Bildes anfügen  
      set end of processedLinks to imgPath 
     end if 
    else if imgPath is in processedLinks then 
     relink curLink to imgPath 
     set curLink to update curLink 
     set curImage to parent of curLink 
     set curFrame to parent of curImage 
     -- die Bildgrössen auf 100 setzen  
     set properties of curImage to {geometric bounds:imgPos} 
     resize curImage horizontal scale 100 vertical scale 100 around center anchor ¬ 
      without considering current scale and considering parents scale 
    end if 
    -- eine eventuelle Spiegelung wiederherstellen 
    tell curImage 
     if rotAng is 180 then 
      set rotation angle of curImage to 180 
     end if 
     if y is less than 0 then 
      set {horizontal scale, vertical scale} to {100, -100} 
     end if 
    end tell 
   end if 
  end repeat 
  -- die Masseinheiten zurücksetzen   
  if resetUnits then 
   tell view preferences to set properties to oldViewPrefs 
  end if 
 end tell 
 -- die Transformations-Vorgaben zurücksetzen  
 if resetTrans then 
  tell transform preferences to set properties to oldTransPrefs 
 end if 
 tell layout window 1 
  set transform reference point to oldAnchor 
 end tell 
 display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 2 
end tell 
 
-- der Handler, welcher in Photoshop das aktuelle Bild skaliert und unter dem gleichen Namen sichert  
on resizeImage(imgPath, horVal, verVal) 
 set filePath to "" 
 tell application "Adobe Photoshop CS2" 
  set bigVers to character 1 of (version as string) as integer 
  -- die alten Masseinheiten sichern    
  set oldRulerUnits to ruler units of settings 
  try 
   set ruler units of settings to point units 
   open file imgPath showing dialogs never 
   set docRef to current document 
   -- das Bild skalieren  
   if bigVers is less than 9 then 
    resize image docRef width percent (horVal / 100) height percent (verVal / 100) resample method bicubic 
   else 
    resize image docRef width percent horVal height percent verVal resample method bicubic 
   end if 
   -- das Bild schärfen  
   set artLayerList to get every art layer of docRef 
   repeat with layerRef in artLayerList 
    try 
     filter layerRef using custom filter with options ¬ 
      {characteristics:{0, 0, 0, 0, 0, 0, 0, -1, 0, 0, 0, -1, 10, -1, 0, 0, 0, -1, 0, 0, 0, 0, 0, 0, 0}, scaling:6, offset:0} 
    end try 
   end repeat 
   -- das Bild sichern  
   set imgDoc to save docRef 
   -- der Variablen 'filePath' den Pfad zuweisen  
   set filePath to file path of imgDoc 
   -- die Masseinheiten zurücksetzen    
   set ruler units of settings to oldRulerUnits 
   close current document saving no 
  on error 
   -- die Masseinheiten zurücksetzen    
   set ruler units of settings to oldRulerUnits 
   try 
    close current document saving no 
   end try 
  end try 
 end tell 
 return filePath 
end resizeImage